Hi,

   Yes, you are right. I just assumed that foe e-mails, you can use any of the free (or pay) e-mail engines out there.

   Here is some code that you can use (you'll need to do some modifications). It uses the Windows CDOSYS component that should be available in 99% of Windows machines out there.

   Cheers!

Michel

----------------------

Private Function SendSmtpMailUsingCdo() As Boolean
    Dim loConfig As Object  ' New CDO.Configuration
    Dim loMsg As Object     ' New CDO.Message
'    Dim loError As Object
'    Dim lcErr As String
    Dim MyFiles() As String
   
    On Error Resume Next
   
    ' Try to create the CDO object (may not be there on newer machines)
    Err.Clear
    Set loConfig = CreateObject("CDO.Configuration")
    Set loMsg = CreateObject("CDO.Message")
   
    If Err.Number <> 0 Then
        olog.LogError True, Err.Number, Err.Description, Err.LastDllError, "SendSmtpMailUsingCdo"
        olog.WriteLog "Try alternate e-mail engine"
        Err.Clear
        Exit Function
    End If
   
    olog.WriteLog "   - Use the CDO SMTP E-Mail engine"
    With loConfig.Fields
       
        .Item(CDO_SCHEMAS & "smtpserver") = Prefs.Mail_SMTP_Server
        .Item(CDO_SCHEMAS & "smtpserverport") = Prefs.Mail_SMTP_Server_Port ' 587 or 25
       
        ' sendusing
        ' Values:
        '    cdoSendUsingPickup = 1
        '    cdoSendUsingPort = 2
        '    cdoSendUsingExchange = 3
        ' Remarks: Use the CdoSendUsing Enum to set this value. If the SMTP service is installed
        '          on the local computer, then the value defaults to cdoSendUsingPickup (1).
        '          Otherwise, if Microsoft Outlook Express is installed, the value defaults to
        '          cdoSendUsingPort (2) and the settings from the default account are used.
        .Item(CDO_SCHEMAS & "sendusing") = 2
       
        ' Authentication. Acceptable values are:
        '   cdoAnonymous = 0 - Perform no authentication.
        '   cdoBasic = 1 - Use the basic (clear text) authentication mechanism.
        '   cdoNTLM = 2 - Use the NTLM authentication mechanism (http://en.wikipedia.org/wiki/NTLM)
        ' as opposed to Prefs.Mail_Authentication: 0 = None, 1 = POP, 2 = Login, 3 = Plain
        '.Item(CDO_SCHEMAS & "smtpauthenticate") = True
        If Prefs.Mail_Authentication = 0 Then
            .Item(CDO_SCHEMAS & "smtpauthenticate") = cdoAnonymous
        Else
            .Item(CDO_SCHEMAS & "smtpauthenticate") = cdoBasic
        End If
       
        ' SSL Support (I choose not to support this for now)
        .Item(CDO_SCHEMAS & "smtpusessl") = 0 ' False
       
        ' Username and Password
        .Item(CDO_SCHEMAS & "sendusername") = Prefs.Mail_Username
        .Item(CDO_SCHEMAS & "sendpassword") = Decrypt(lblMail(6).Caption, fUnicodeUser)
       
        ' Timeout value
        .Item(CDO_SCHEMAS & "smtpconnectiontimeout") = 10 ' 10 second timeout
       
        ' Register the changes w the CDO component
        .Update
    End With
   
    With loMsg
        Set .Configuration = loConfig
       
        If fUnicodeUser Then
            .BodyPart.Charset = "unicode-1-1-utf-8"
        End If
       
        .From = Prefs.Mail_From
        .To = lblMail(0).Caption
        .CC = lblMail(1).Caption
        .BCC = lblMail(2).Caption
        .Subject = lblMail(3).Caption
        .TextBody = lblMail(4).Caption
       
        ' Attachments
        olog.WriteLog "   - Attaching Files...."
        MyFiles = Split(lblMail(5).Caption, ";")
        For i = 0 To UBound(MyFiles)
            olog.WriteLog "     >>" & GetFilePart(MyFiles(i))
            .AddAttachment MyFiles(i)
        Next
       
        Err.Clear
        .Send
       
        ' Check for Errors
        If Err.LastDllError = 0 Then
            ' Success
            olog.WriteLog SUCCESS
            TempStr = str$(True)
            SendSmtpMailUsingCdo = True
        Else
            TempStr = Trim$(str$(Err.LastDllError))
            olog.WriteLog FAILED & " CDO Mail Engine Error Code is:" & TempStr
            olog.LogError True, Err.Number, Err.Description, Err.LastDllError, "SendSmtpMailUsingCdo"
        End If
   
    End With

End Function

Hi David,

   Yes, the outlook sample code is a great alternative for those people that have it (I had assumed you wanted the more generic code).

   Yes, I will consider it for the next version. Indeed, for the next version, I will be creating a common ActiveX component which will be shared between PDF reDirect and for the VBA sample code so that I do not need to port the code from one to the other.

   Cheers!

Michel